Envoyer « en tant que » ou « depuis » (de/from) une autre adresse mail par défaut

Si vous avez besoin de faire en sorte que l’envoi par défaut, à la réponse ou depuis un nouveau mail, quelque soit le compte d’envoi séléctionné, les mails partent systématiquement depuis une même adresse, il faut séléctionner le compte d’envoi depuis le champ « De ».

Hors, il n’est pas possible de choisir « par défaut » ce compte depuis pour tout mail en réponse mais seulement depuis les nouveaux mails.

La solution suivante permet de choisir, pour tout nouveaux messages ou réponses, l’adresse d’envoi, et ce quel que soit le compte de réponse. En gros, ce workaround « remplace » le compte d’envoi par celui choisi dans le script.

1. Attribuer les droits sur la boite mail partagée

Le script suivant fonctionne dans le cas ou les utilisateurs en bénéficiant sur Outlook disposent de droits sur la boite mail partagée permettant l’envoi (et donc l’affichage frontal pour le destinataire).

Il faudra donc au préalable autorisé les utilisateurs à « Envoyer en tant que » et « Envoyer de la part de » depuis l’interface d’administration d’Office 365. Noter que l’activation de cette option peut prendre plusieurs heures :

Intégraton du script dans Outlook

1. Depuis Outlook, faire la combinaison Alt+F11 pour arriber dans l’éditeur de script Visual Basic

2. Double-cliquez sur ThisOutlookSession :

3. Coller le code suivant :

'================================================================================
'Description: Outlook macro to automatically set a different
'             From address.
'
'Comment: You can set the email address at the bottom of the code.
'         Uncomment the myOlExp_InlineResponse sub to also make it
'         work with the Reading Pane reply feature of Outlook 2013/2016/2019/365.
'
' author : Robert Sparnaaij
' version: 1.1
' website: https://www.howto-outlook.com/howto/setfromaddress.htm
'================================================================================
Dim WithEvents objInspectors As Outlook.Inspectors
Dim WithEvents objMailItem As Outlook.MailItem
Dim WithEvents myOlExp As Outlook.Explorer
Private Sub Application_Startup()
    Initialize_handler
End Sub
Public Sub Initialize_handler()
    Set objInspectors = Application.Inspectors
    Set myOlExp = Application.ActiveExplorer
End Sub
Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
        Set objMailItem = Inspector.CurrentItem
        If objMailItem.Sent = False Then
            Call SetFromAddress(objMailItem)
        End If
    End If
End Sub
'Uncomment the next 3 lines to enable Outlook 2013/2016/2019/365 Reading Pane Reply
Private Sub myOlExp_InlineResponse(ByVal objItem As Object)
    Call SetFromAddress(objItem)
End Sub
Public Sub SetFromAddress(oMail As Outlook.MailItem)
    ' Set your preferred default From address below.
    ' Exchange permissions determine if it is actually stamped
    ' as "Sent On Behalf Of" or "Sent As".
    ' The address is not properly updated for the InlineResponse
    ' feature in Outlook 2013/2016/365. This is only a visual bug.
    oMail.SentOnBehalfOfName = "compte@mail.com"
End Sub

4. Remplacer l’adresse mail « compte@mail.com » de la fonction SetFromAddress par celle de l’adresse partagée

5. Redémarrer Outlook

Activer les macros sur Outlook

Pour que cette macro puisse fonctionner, il fait activer les macros sur Outlook.

Pour cela, il faut aller dans le Centre de gestion de la confidentialité. Pour cela :

Fichier > Options > Centre de gestion de la confidentialité > Paramètres du Centre de gestion de la confidentialité > Paramètres des macros > « Activer toutes les macros (non recommandé, exécution possible de code potentiellement dangereux) ».

Valider les réglages.

Cas particulier

Si vous avez besoin que ce « remplacement » ai lieu pour un compte spécifique, il faut modifier la fonction SetFromAddress par cela :

If Instr (1, oMail.SendUsingAccount, "@domain.com", vbTextCompare) > 0 Then 
      oMail.SentOnBehalfOfName = delegate@domain.com
End If

Ici, remplaceer « @domain.com » par l’adresse mail du compte en question.

Source : https://robert365.com/article/setfromaddress#macrocode